8  センサと LED 表示

8.1 加速度センサ (LSM6DS3TR-C)

XIAO nRF52840 Sense には、6 軸 IMU(3 軸加速度 + 3 軸ジャイロ)LSM6DS3TR-C が I²C で接続されています。

#include "drv_imu.h"

#if USE_IMU
#include <LSM6DS3.h>
#include <Wire.h>

static LSM6DS3 s_imu(I2C_MODE, 0x6A);

void imu_init()
{
  // XIAO nRF52840 Sense の IMU は電源ピンで ON にする必要がある
  pinMode(PIN_LSM6DS3TR_C_POWER, OUTPUT);
  digitalWrite(PIN_LSM6DS3TR_C_POWER, HIGH);
  delay(50);
  s_imu.settings.accelRange = 4; // ±4 g
  if (s_imu.begin() != 0)
  {
    Serial.println("IMU init failed");
  }
}

uint16_t imu_read_magnitude_mg()
{
  // I2C 通信を伴うので、割り込みではなくハンドラ(メインループ)から呼ぶ
  float x = s_imu.readFloatAccelX();
  float y = s_imu.readFloatAccelY();
  float z = s_imu.readFloatAccelZ();
  return (uint16_t)(sqrtf(x * x + y * y + z * z) * 1000.0f);
}

#else
// IMU がないボード用の疑似データ(1000 mg を中心にゆっくり揺れる)
void imu_init() {}

uint16_t imu_read_magnitude_mg()
{
  float t = millis() / 1000.0f;
  return (uint16_t)(1000.0f + 150.0f * sinf(2.0f * PI * 0.2f * t) + random(-20, 21));
}
#endif

8.1.1 ポイント

  • IMU の電源ピン: Sense 版の IMU は PIN_LSM6DS3TR_C_POWER を HIGH にしないと電源が入らない。使わないときに LOW にすれば省電力にできる
  • どこで読むか: I²C の通信には数百 µs〜数 ms かかり、ライブラリの内部で割り込みや待ちを使う。ISR やタイマーのコールバックの中ではなく、ハンドラ(メインループ)で読む。タイマーは「読む時刻になった」というイベントを積むだけ
  • ボードの違いの吸収: USE_IMU が 0 のときは疑似データを返すので、IMU のない XIAO nRF52840 でも、それ以外の部分(状態遷移・BLE)を同じように試せる

8.1.2 合成加速度

\[ |a| = \sqrt{a_x^2 + a_y^2 + a_z^2} \]

は、デバイスの 向きによらない 動きの大きさです。静止時は重力加速度だけなので約 1 g(1000 mg)になり、動くとその周りで変動します。

ノートセンサの FIFO

このサンプルでは 100 ms ごとに 1 回読んでいますが、より高いサンプリング周波数(例: 100 Hz 以上)で等間隔に取りたい場合は、IMU 内部の FIFO にデータをためさせ、FIFO が一定量たまったら割り込み を出させて、まとめて読み出す方法が効率的です。CPU はその間スリープできます。この割り込みも、ISR ではイベントを積むだけにして、読み出しはハンドラで行います。

8.2 LED 表示:ノンブロッキングに

#include "drv_led.h"

// XIAO nRF52840 の RGB LED は LOW で点灯する(アクティブ Low)
static void write_rgb(bool r, bool g, bool b)
{
  digitalWrite(LED_RED, r ? LOW : HIGH);
  digitalWrite(LED_GREEN, g ? LOW : HIGH);
  digitalWrite(LED_BLUE, b ? LOW : HIGH);
}

void led_init()
{
  pinMode(LED_RED, OUTPUT);
  pinMode(LED_GREEN, OUTPUT);
  pinMode(LED_BLUE, OUTPUT);
  write_rgb(false, false, false);
}

void led_set(LedColor color)
{
  write_rgb(color == LED_COLOR_RED, color == LED_COLOR_GREEN, color == LED_COLOR_BLUE);
}

void led_blink(LedColor color, uint16_t on_ms, uint16_t period_ms)
{
  // 経過時間を周期で割った余りで点灯・消灯を決める(状態を持たない)
  bool on = (millis() % period_ms) < on_ms;
  led_set(on ? color : LED_COLOR_OFF);
}

8.2.1 delay で点滅させてはいけない

// 悪い例: ハンドラの中で点滅
led_set(LED_COLOR_GREEN); delay(100);
led_set(LED_COLOR_OFF);   delay(100);
led_set(LED_COLOR_GREEN); delay(100);
led_set(LED_COLOR_OFF);

この 300 ms の間、メインループは止まり、イベントの処理が進みません。100 ms ごとのタイマーイベントが 3 つたまり、BLE のコマンドへの応答も遅れます。

8.2.2 millis() から点灯・消灯を計算する

led_blink() は、現在時刻を周期で割った余り で点灯か消灯かを決めます。

bool on = (millis() % period_ms) < on_ms;
  • 状態(前回いつ点けたか)を持たないので、どこから何回呼ばれても破綻しない
  • 呼ばれる頻度が十分高ければ(このサンプルでは 100 ms タイマーのおかげで 10 Hz 以上)、見た目どおりに点滅する

8.2.3 ui_update() の位置

main.cpp の ui_update() は、イベントを 1 つ処理するたびに、現在の状態から表示を決め直します。表示を「状態の関数」にしておくと、

  • ハンドラの中で LED を操作しなくてよい(ハンドラは状態遷移と処理に集中できる)
  • 状態を追加したとき、表示の変更は ui_update() の 1 か所で済む

という利点があります。

状態 LED
WAIT(未接続) 緑、2 秒に 1 回短く点滅
WAIT(接続中) 青、1 秒に 1 回短く点滅
MEAS 赤、0.5 秒に 1 回短く点滅
ヒント演習

100 ms タイマーを止めた(timer_init() を呼ばない)状態で待機中の LED を観察しよう。点滅はどうなるか? なぜか?

ui_update() はイベントを処理したときにしか呼ばれないため、イベントが来なければ LED は更新されず、点灯または消灯のまま止まります。表示の更新を イベントに便乗 させている設計の限界です。表示のためだけに一定周期のイベント(タイマー)を用意するか、LED の点滅をハードウェア(PWM 周辺回路)に任せる方法があります。